Projects/Mini Plotter

From Playful Exploration
Jump to navigation Jump to search

STM32F103C_stepper.ino

Notes Code Image
Main routines
#include <Arduino.h>
#include <io.h>

#include <plot.h>

//http://docs.leaflabs.com/static.leaflabs.com/pub/leaflabs/maple-docs/0.0.12/lang/api/analogwrite.html
HardwareTimer timer(3);

int servo_min = map(1, 0, 20, 0, 65535);
int servo_max = map(2, 0, 20, 0, 65535);

#define angle(deg) map(deg, 0, 180, servo_min, servo_max)
#define pen(on) (pwmWrite(PB0, angle(on ? 120 : 85)), delay(80))

volatile int ww = 900;
volatile int w = ww;

Plot plot(2);

void setup()
{
  Serial.begin(9600);
  Serial.print("Hello!");
  pinMode(PA0, OUTPUT);
  pinMode(PA1, OUTPUT);
  pinMode(PA2, OUTPUT);
  pinMode(PA3, OUTPUT);
  pinMode(PA4, OUTPUT);
  pinMode(PA5, OUTPUT);
  pinMode(PA6, OUTPUT);
  pinMode(PA7, OUTPUT);
  pinMode(PC13, OUTPUT);

  timer.setPeriod(20000);
  pinMode(PB0, PWM);
  pen(0);

  for (int i = 5; i--;)
  {
    digitalWrite(PC13, 0);
    delay(200);
    digitalWrite(PC13, 1);
    delay(500);
  }

  //for (int i = 0; i < 180; i++) { pwmWrite(PB0, angle(i)); delay(5000/180); }
  //for (int i = 0; i < 5; i++) { pen(1); delay(1000); pen(0); delay(1000); }

  plot.homing(ww);
  w = ww / 2;
  plot.moveTo(w, w);
  plot.zero();
  delay(1000);
}

int ar[] = {20, 30, 40, 33};
const unsigned int sz = sizeof(ar) / sizeof(int);

void loop()
{
  if (loop3())   //<-- change the loop number to run different plottings
    return;

  pen(0);
  plot.moveTo(ww / 2, ww / 2);
  plot.sleep();
  while (1)
    ;
}
Square Spiral
bool loop1()
{
  sq0(w);
  w -= 40;
  return w > 0;
}

void sq0(int w)
{
  pen(1);
  plot.moveTo(-w, -w);
  plot.moveTo(-w, w);
  plot.moveTo(w, w);
  plot.moveTo(w, -w);
}
https://youtu.be/ypERBG_X-Vs
Rotating Squares
bool loop2()
{
  sq1(w);
  sq2(w);
  w /= 2;
  return w > 10;
}

void sq1(int w)
{
  plot.moveTo(-w, -w);
  pen(1);
  plot.moveTo(-w, w);
  plot.moveTo(w, w);
  plot.moveTo(w, -w);
  plot.moveTo(-w, -w);
  pen(0);
}

void sq2(int w)
{
  plot.moveTo(-w, 0);
  pen(1);
  plot.moveTo(0, -w);
  plot.moveTo(w, 0);
  plot.moveTo(0, w);
  plot.moveTo(-w, 0);
  pen(0);
}
Hilbert Curve
bool loop3()
{
  // 1-1
  // 2-3
  // 3-7
  // 4-15
  // 5-31
  int r = 4;
  int x = 2 * w / ((1 << r) - 1);
  plot.moveTo(-w, -w);
  pen(1);
  hilbert(r, x, 0);

  return false;
}

void hilbert(int depth, int dx, int dy)
{
  if (depth > 1)
    hilbert(depth - 1, dy, dx);
  plot.moveRel(dx, dy);
  if (depth > 1)
    hilbert(depth - 1, dx, dy);
  plot.moveRel(dy, dx);
  if (depth > 1)
    hilbert(depth - 1, dx, dy);
  plot.moveRel(-dx, -dy);
  if (depth > 1)
    hilbert(depth - 1, -dy, -dx);
}

plot library

plot.h
#ifndef PLOT_H_
#define PLOT_H_

#include "Arduino.h"

class Plot
{
  public:
    Plot(int slow);
    void zero();
    void sleep();
    void homing(int steps);
    void moveTo(int x1, int y1);
    void moveRel(int x, int y);

  private:
    void step1(int sx, int sy);
    int stepper_map[8] = {11, 10, 14, 6, 7, 5, 13, 9};
    int slow = 2;
    int xx;
    int yy;
};

#endif /* PLOT_H_ */
plot.cpp
#include "plot.h"
#include <Arduino.h>

Plot::Plot(int slow)
{
	this->slow = slow;
	zero();
}

void Plot::sleep()
{
	GPIOA->regs->BSRR = 0b11111111 << 16;
}

void Plot::step1(int sx, int sy)
{
	xx += sx;
	yy += sy;

	int op = stepper_map[yy & 7] << 4 | stepper_map[xx & 7];
	// trun stepper off if not moving
	if (sx == 0)
		op |= 0b00001111;
	if (sy == 0)
		op |= 0b11110000;
	GPIOA->regs->BSRR = (0b11111111 << 16) | op;
	delay(slow);
}

void Plot::zero()
{
	xx = 0;
	yy = 0;
}

void Plot::moveTo(int x1, int y1)
{
	int x0 = xx;
	int y0 = yy;
	int steep = abs(y1 - y0) > abs(x1 - x0);
	if (steep)
	{
		x0 ^= y0;
		y0 ^= x0;
		x0 ^= y0;
		x1 ^= y1;
		y1 ^= x1;
		x1 ^= y1;
	} //swap
	int deltax = abs(x1 - x0);
	int deltay = abs(y1 - y0);
	int error = deltax / 2;

	int incX = x0 < x1 ? 1 : -1;
	int incY = y0 < y1 ? 1 : -1;

	int goY = 0;

	int x = deltax;
	while (x-- > 0)
	{
		if (steep)
			step1(goY, incX);
		else
			step1(incX, goY);
		goY = 0;

		error = error - deltay;
		if (error < 0)
		{
			goY = incY;
			error = error + deltax;
		}
	}
}
void Plot::moveRel(int x, int y)
{
	moveTo(xx + x, yy + y);
}

void Plot::homing(int steps)
{
	zero();
	moveTo(-steps, -steps);
	zero();
	moveTo(8, 8);
	zero();
}